PC World 2001 October/PCWorld_2001-10_cd.bin/Software/TemaCD/3dcanvas/3DCanv13.CAB/Export DirectX.CS

Text File | 2001-08-12 | 33KB | 1,061 lines

Language = VBScript

'*********************************************************************************
' Purpose:  Exports the scene in DirectX format.
'           Determine the file to be exported to.
'*********************************************************************************

Option Explicit          'require variable declarations

Private mCanvasApp       'provide the CanvasApp object to the entire module

Sub Main (CanvasApp)

    Dim ExportFileName
    Dim FileSystemObject
    Dim FileObject
    Dim CommonDialog
    Const cdlOFNHideReadOnly = &H4
    Const cdlOFNPathMustExist = &H800
    Const cdlOFNOverwritePrompt = &H2
    Const ErrorCancelSelected = 32755
    Dim Scene
    Dim Canceled

    'there are useful functions provided by the CanvasApp so make it
    'available to the whole module
    Set mCanvasApp = CanvasApp

    On Error Resume Next
    Set CommonDialog = CreateObject("MSComDlg.CommonDialog")

    'if an error occured then user doesn't have MSComDlg available
    If Err.Number <> 0 Then
        Err.Clear
        On Error Goto 0

        'since MSComDlg was missing we will default a file name
        ExportFileName = "c:\export.x"

        'let the user know where we are putting the file
        MsgBox "Scene will be exported to """ & ExportFileName & """"

        Canceled = False
    Else
        On Error Goto 0
        With CommonDialog

            'start with no file name at all
            .FileName = ""

            'allocate the required space
            .MaxFileSize = 256

            'the path must exist, can't be read only, and should warn about overwriting
            .flags = cdlOFNPathMustExist Or cdlOFNHideReadOnly Or cdlOFNOverwritePrompt

            'we want only X
            .Filter = "DirectX (*.X)|*.X"

            'call it an error if someone cancels
            .CancelError = True

            'show the save box
            On Error Resume Next
            .ShowSave

            'Check to see if they canceled
            If Err.Number = 0 Then
                ExportFileName = .FileName
                Canceled = False
            Else
                Canceled = True
            End if

        End With
    End If

    'if they didn't cancel
    If Not Canceled Then
        On Error Goto 0

        'get a file system object
        Set FileSystemObject = CreateObject("Scripting.FileSystemObject")

        'create a file
        Set FileObject = FileSystemObject.CreateTextFile(ExportFileName, True)

        'get the scene
        Set Scene = CanvasApp.GetActiveScene

        'write the scene
        ExportScene FileObject, Scene

        'close the file
        FileObject.Close

        'tell them we are done
        MsgBox "File Export Complete"

    End If

End Sub

'*********************************************************************************
' Purpose: Main Export Function
'*********************************************************************************

Sub ExportScene (FileObject, Scene)


    Dim RootFrame

    'Write the header
    WriteHeader FileObject

    'Write Materials
    WriteMaterials FileObject, Scene

    'Get the Scene Frame
    Set RootFrame = Scene.GetRootFrame

    'Write the Scene
    WriteFrame FileObject, RootFrame, 0

    'Write the Animation Information as an AnimationSet
    WriteAnimationSet FileObject, RootFrame


End Sub

'*********************************************************************************
' Purpose: Write the DirectX Header
'*********************************************************************************

Sub WriteHeader (FileObject)

    'write the DirectX required header
    FileObject.WriteLine("xof 0302txt 0032")
    FileObject.WriteLine("Header {1; 0; 1;}")

    'write a blank line
    FileObject.WriteBlankLines(1)

    'write a comment indicating that the scene was created by 3D Canvas
    FileObject.WriteLine("// Created by 3D Canvas")

    'write a blank line
    FileObject.WriteBlankLines(1)

End Sub

'*********************************************************************************
' Purpose: Write the materials.
'*********************************************************************************

Sub WriteMaterials (FileObject, Scene)

    Dim ObjectCount    'Number of objects in the scene
    Dim ObjectIndex    'Index of Object being processed
    Dim Object         'Object being processed
    Dim MaterialCount  'Number of material for an object
    Dim MaterialIndex  'Index of the Material being processed
    Dim Material       'Material being processed

    'Get the Object Count
    ObjectCount = Scene.GetObjectCount

    'run through the objects one at a time
    For ObjectIndex = 0 to ObjectCount - 1

        'get the object
        Set Object = Scene.GetObject(ObjectIndex)

        'get the number of materials used by the object
        MaterialCount = Object.GetMaterialCount

        'run through the materials exporting one material at a time
        For MaterialIndex = 0 to MaterialCount - 1
            'get the Material
            Set Material = Object.GetMaterial(MaterialIndex)

            WriteIndividualMaterial FileObject, Material, Object.GetID, MaterialIndex
        Next

    Next

End Sub


'*********************************************************************************
' Purpose: Write an individual material
'*********************************************************************************

Sub WriteIndividualMaterial (FileObject, Material, ObjectID, MaterialID)

    Dim DirectXColorRed
    Dim DirectXColorGreen
    Dim DirectXColorBlue
    Dim DirectXColorAlpha
    Dim DirectXPower
    Dim DirectXSpecularRed
    Dim DirectXSpecularGreen
    Dim DirectXSpecularBlue
    Dim DirectXEmissiveRed
    Dim DirectXEmissiveGreen
    Dim DirectXEmissiveBlue
    Dim CanvasAmbient
    Dim TextureFileName

    'get the DirectX equivalents of the material

    'the color - this is easy
    Material.GetColor DirectXColorRed, DirectXColorGreen, DirectXColorBlue

    'the alpha
    DirectXColorAlpha = Material.GetTranslucent
    DirectXColorAlpha = 1 - (DirectXColorAlpha / 100)

    'the Power
    DirectXPower = Material.GetSpecular
    If DirectXPower <> 0 Then
        DirectXPower = 250 - (DirectXPower * 2.49)
    End If

    'the 3D Canvas Ambient - which is Direct3D Emissive
    CanvasAmbient = Material.GetAmbient
    DirectXEmissiveRed = DirectXColorRed * (CanvasAmbient / 100)
    DirectXEmissiveGreen = DirectXColorGreen * (CanvasAmbient / 100)
    DirectXEmissiveBlue = DirectXColorBlue * (CanvasAmbient / 100)

    'output the DirectX material
    FileObject.WriteLine("Material mtx3dc_" & CStr(CLng(ObjectID)) & "_" & CStr(CLng(MaterialID)) & " {")
    FileObject.WriteLine(Space(4) & mCanvasApp.FormatScientific(DirectXColorRed) & ";" & mCanvasApp.FormatScientific(DirectXColorGreen) & ";" & mCanvasApp.FormatScientific(DirectXColorBlue) & ";" & mCanvasApp.FormatScientific(DirectXColorAlpha) & ";;")
    FileObject.WriteLine(Space(4) & mCanvasApp.FormatScientific(DirectXPower) & ";")
    FileObject.WriteLine(Space(4) & mCanvasApp.FormatScientific(1) & ";" & mCanvasApp.FormatScientific(1) & ";" & mCanvasApp.FormatScientific(1) & ";;") 'always white in 3D Canvas
    FileObject.WriteLine(Space(4) & mCanvasApp.FormatScientific(DirectXEmissiveRed) & ";" & mCanvasApp.FormatScientific(DirectXEmissiveGreen) & ";" & mCanvasApp.FormatScientific(DirectXEmissiveBlue) & ";;")


    'output the texture (if there is any)
    TextureFileName = Material.GetTextureFileName
    If TextureFileName <> "" Then
        FileObject.WriteLine Space(4) & "TextureFileName {"
        FileObject.WriteLine Space(8) & Chr(34) & TextureFileName & Chr(34) & ";"
        FileObject.WriteLine Space(4) & "}"
    End If

    FileObject.WriteLine("}")

    'write a blank line
    FileObject.WriteBlankLines(1)

End Sub

'*********************************************************************************
' Purpose: Write a frame.
'          Warning: This uses recursion!
'*********************************************************************************

Sub WriteFrame (FileObject, Frame, Level)
    Dim ChildLevel
    Dim Indent
    Dim ChildFrameCount
    Dim ChildFrame
    Dim ChildFrameIndex

    'determine the child level
    ChildLevel = Level + 1

    'determine the amount of fill
    Indent = Space(Level * 4)

    'write the opening frame block
    FileObject.WriteLine(Indent & "Frame x3dc_" & CStr(CLng(Frame.GetID)) & " {")

    'write a blank line
    FileObject.WriteBlankLines(1)

    'Write the transformation matrix
    WriteFrameTransformMatrix FileObject, Frame, ChildLevel

    'Write the objects that have this frame as a parent
    WriteFrameObjects FileObject, Frame, ChildLevel

    'get the # of childrend the frame has
    ChildFrameCount = Frame.GetChildCount

    'run throught the children
    For ChildFrameIndex = 0 To ChildFrameCount -1
        Set ChildFrame = Frame.GetChild(ChildFrameIndex)

        'Recursion!
        WriteFrame FileObject, ChildFrame, ChildLevel

        'release the frame
        Set ChildFrame = Nothing
    Next

    'write the closing of the frame block
    FileObject.WriteLine(Indent & "}")

    'write a blank line
    FileObject.WriteBlankLines(1)

End Sub

'*********************************************************************************
' Purpose: Write a frame's transform matrix.
'*********************************************************************************

Sub WriteFrameTransformMatrix (FileObject, Frame, Level)

    Dim Indent
    Dim ParentFrame
    Dim Mat00
    Dim Mat01
    Dim Mat02
    Dim Mat03
    Dim Mat10
    Dim Mat11
    Dim Mat12
    Dim Mat13
    Dim Mat20
    Dim Mat21
    Dim Mat22
    Dim Mat23
    Dim Mat30
    Dim Mat31
    Dim Mat32
    Dim Mat33

    'determine the amount of indent
    Indent = Space(Level * 4)

    'write the opening mesh block
    FileObject.WriteLine(Indent & "FrameTransformMatrix {")

    'get the parent frame
    set ParentFrame = Frame.GetParent

    'if we are at the root of the scene (no parent)
    'then we set the transform matrix ourselves
    If ParentFrame Is Nothing Then
        Mat00 = 1
        Mat11 = 1
        Mat22 = 1
        Mat33 = 1
    Else 'otherwise get the transform matrix
        Frame.GetTransformMatrix ParentFrame _
        , Mat00 _
        , Mat01 _
        , Mat02 _
        , Mat03 _
        , Mat10 _
        , Mat11 _
        , Mat12 _
        , Mat13 _
        , Mat20 _
        , Mat21 _
        , Mat22 _
        , Mat23 _
        , Mat30 _
        , Mat31 _
        , Mat32 _
        , Mat33
    End If

    'write the transformation matrix
    FileObject.WriteLine(Indent & Space(4) & mCanvasApp.FormatScientific(Mat00) & ", " & mCanvasApp.FormatScientific(Mat10) & ", " & mCanvasApp.FormatScientific(Mat20) & ", " & mCanvasApp.FormatScientific(Mat30) & ",")
    FileObject.WriteLine(Indent & Space(4) & mCanvasApp.FormatScientific(Mat01) & ", " & mCanvasApp.FormatScientific(Mat11) & ", " & mCanvasApp.FormatScientific(Mat21) & ", " & mCanvasApp.FormatScientific(Mat31) & ",")
    FileObject.WriteLine(Indent & Space(4) & mCanvasApp.FormatScientific(Mat02) & ", " & mCanvasApp.FormatScientific(Mat12) & ", " & mCanvasApp.FormatScientific(Mat22) & ", " & mCanvasApp.FormatScientific(Mat32) & ",")
    FileObject.WriteLine(Indent & Space(4) & mCanvasApp.FormatScientific(Mat03) & ", " & mCanvasApp.FormatScientific(Mat13) & ", " & mCanvasApp.FormatScientific(Mat23) & ", " & mCanvasApp.FormatScientific(Mat33) & ";;")

    'write the closing mesh block
    FileObject.WriteLine(Indent & "}")

End Sub


'*********************************************************************************
' Purpose: write the objects that are contained in the frame
'*********************************************************************************

Sub WriteFrameObjects (FileObject, Frame, Level)

    Dim ObjectCount
    Dim ObjectIndex
    Dim Object

    'get the number of objects on this frame
    ObjectCount = Frame.GetObjectCount

    'run through the objects exporting them
    For ObjectIndex = 0 to ObjectCount - 1
        'Get the Object
        Set Object = Frame.GetObject(ObjectIndex)

        WriteObject FileObject, Object, Level
    Next

End Sub

'*********************************************************************************
' Purpose: write an object
'*********************************************************************************

Sub WriteObject (FileObject, Object, Level)

    Dim Indent


    'if the object isn't empty (it could be if the last face was deleted)
    If Object.GetFaceCount > 0 Then
        'determine the amount to indent
        Indent = Space(Level * 4)

        'write the opening mesh block
        FileObject.WriteLine (Indent & "Mesh mx3dc_" & CStr(CLng(Object.GetID)) & " {" )

        WritePoints FileObject, Object, Level + 1
        WriteFaceMaterials FileObject, Object, Level + 1
        WriteNormals FileObject, Object, Level + 1
        WriteFaceWraps FileObject, Object, Level + 1
        WriteTextureCoordinates FileObject, Object, Level + 1
        WriteSkeletal FileObject, Object, Level

        'write the closing mesh block
        FileObject.WriteLine ( Indent & "}" )
    End If

    'write a blank line
    FileObject.WriteBlankLines(1)

End Sub


'*********************************************************************************
' Purpose: write the points of an object
'*********************************************************************************

Sub WritePoints(FileObject, Object, Level)

    Dim Indent
    Dim PointCount
    Dim Point
    Dim Delimiter
    Dim X
    Dim Y
    Dim Z
    Dim FaceCount
    Dim FaceIndex
    Dim PointIndex
    Dim Face
    Dim FacePointCount
    Dim FaceData

    'determine the amount to indent
    Indent = Space(Level * 4)

    'get the number of points in the object
    PointCount = Object.GetPointCount

    'write the number of points
    FileObject.WriteLine Indent & CStr(CLng(PointCount)) & ";"

    'write the points
    For PointIndex = 0 To PointCount - 1

        'if the last point then we need to terminate the line differently
        If PointIndex = PointCount - 1 Then
            Delimiter = ";"
        Else
            Delimiter = ","
        End If

        'get the point
        Object.GetPoint PointIndex, X, Y, Z

        FileObject.WriteLine Indent & mCanvasApp.FormatScientific(X) & "; " & mCanvasApp.FormatScientific(Y) & "; " & mCanvasApp.FormatScientific(Z) & ";" & Delimiter

    Next


    'get the number of faces in the object
    FaceCount = Object.GetFaceCount

    'write the face count
    FileObject.WriteLine Indent & CStr(CLng(FaceCount)) & ";"

    'write the faces
    For FaceIndex = 0 to FaceCount -1

        'get the face
        Set Face = Object.GetFace(FaceIndex)

        'get the number of points in the face
        FacePointCount = Face.GetPointCount

        'the number of points in the face
        FaceData = CStr(CLng(FacePointCount)) & ";"

        'run through the points
        For PointIndex = 0 To FacePointCount - 1
            'if we are on the last point we end have a different delimiter
            If PointIndex = FacePointCount - 1 Then
                Delimiter = ";"
            Else
                Delimiter = ","
            End If

            'get the point
            Point = Face.GetPoint(PointIndex)

            'add it to the face data
            FaceData = FaceData & CStr(CLng(Point)) & Delimiter
        Next

        'if we are on the last face, then we end the line differently
        If FaceIndex = FaceCount -1 Then
            Delimiter = ";"
        Else
            Delimiter = ","
        End If

        'write the face line
        FileObject.WriteLine Indent & FaceData & Delimiter

    Next

End Sub


'*********************************************************************************
' Purpose: write the materials for a face
'*********************************************************************************

Sub WriteFaceMaterials(FileObject, Object, Level)

    Dim Indent
    Dim ObjectMaterialCount
    Dim FaceCount
    Dim MaterialIndex
    Dim FaceIndex
    Dim Delimiter
    Dim FaceMaterial

    'determine the amount to indent
    Indent = Space(Level * 4)

    'get the number of materials
    ObjectMaterialCount = Object.GetMaterialCount

    'the header
    FileObject.WriteLine Indent & "MeshMaterialList {"

    'the number of materials
    FileObject.WriteLine Indent & Space(4) & CStr(CLng(ObjectMaterialCount)) & ";"

    'if there is only one material it can be applied to the whole object
    If ObjectMaterialCount = 1 Then
        FileObject.WriteLine Indent & Space(4) & "1;"
        FileObject.WriteLine Indent & Space(4) & "0;;"

    'otherwise each face's material must be written
    Else

        'get the number of faces
        FaceCount = Object.GetFaceCount

        FileObject.WriteLine Indent & Space(4) & CStr(CLng(FaceCount)) & ";"
        For FaceIndex = 0 To FaceCount - 1
            'get the face
            FaceMaterial = Object.GetFaceMaterialIndex(FaceIndex)

            'the last face must have a different delimiter
            If FaceIndex = FaceCount - 1 Then
                Delimiter = ";;"
            Else
                Delimiter = ","
            End If

            FileObject.WriteLine Indent & Space(4) & CStr(CLng(FaceMaterial)) & Delimiter
        Next
    End If

    'the materials
    For MaterialIndex = 0 To ObjectMaterialCount - 1
        FileObject.WriteLine Indent & Space(4) & "{mtx3dc_" & CStr(CLng(Object.GetID)) & "_" & CStr(CLng(MaterialIndex)) & "}"
    Next

    'write the closing block
    FileObject.WriteLine Indent & "}"

End Sub


'*********************************************************************************
' Purpose: write the normals for an object
'*********************************************************************************

Sub WriteNormals(FileObject, Object, Level)

    Dim Indent
    Dim NormalCount
    Dim Normal
    Dim Delimiter
    Dim X
    Dim Y
    Dim Z
    Dim FaceCount
    Dim FaceIndex
    Dim NormalIndex
    Dim Face
    Dim FaceNormalCount
    Dim FaceData

    'determine the amount to indent
    Indent = Space(Level * 4)

    'write the normals
    FileObject.WriteLine Indent & "MeshNormals {"

    'get the number of normals in the object
    NormalCount = Object.GetNormalCount

    'write the number of normals
    FileObject.WriteLine Indent & Space(4) & CStr(CLng(NormalCount)) & ";"

    'write the normals
    For NormalIndex = 0 To NormalCount - 1

        'if the last normal then we need to terminate the line differently
        If NormalIndex = NormalCount - 1 Then
            Delimiter = ";"
        Else
            Delimiter = ","
        End If

        'get the normal
        Object.GetNormal NormalIndex, X, Y, Z

        FileObject.WriteLine Indent & Space(4) & mCanvasApp.FormatScientific(X) & "; " & mCanvasApp.FormatScientific(Y) & "; " & mCanvasApp.FormatScientific(Z) & ";" & Delimiter

    Next


    'get the number of faces in the object
    FaceCount = Object.GetFaceCount

    'write the face count
    FileObject.WriteLine Indent & Space(4) & CStr(CLng(FaceCount)) & ";"

    'write the faces
    For FaceIndex = 0 to FaceCount -1

        'get the face
        Set Face = Object.GetFace(FaceIndex)

        'get the number of normals in the face
        FaceNormalCount = Face.GetNormalCount

        'the number of normals in the face
        FaceData = CStr(CLng(FaceNormalCount)) & ";"

        'run through the normals
        For NormalIndex = 0 To FaceNormalCount - 1
            'if we are on the last normal we end have a different delimiter
            If NormalIndex = FaceNormalCount - 1 Then
                Delimiter = ";"
            Else
                Delimiter = ","
            End If

            'get the normal
            Normal = Face.GetNormal(NormalIndex)

            'add it to the face data
            FaceData = FaceData & CStr(CLng(Normal)) & Delimiter
        Next

        'if we are on the last face, then we end the line differently
        If FaceIndex = FaceCount -1 Then
            Delimiter = ";"
        Else
            Delimiter = ","
        End If

        'write the face line
        FileObject.WriteLine Indent & Space(4) & FaceData & Delimiter

    Next

    'write the closing normal block
    FileObject.WriteLine Indent & "}"

End Sub

'*********************************************************************************
' Purpose: write the wrap flags (texture topology) for the faces
'*********************************************************************************

Sub WriteFaceWraps(FileObject, Object, Level)

    Dim Indent
    Dim Delimiter
    Dim FaceIndex
    Dim Face
    Dim WrapU
    Dim WrapV
    Dim FaceCount

    'determine the amount to indent
    Indent = Space(Level * 4)

    'the header
    FileObject.WriteLine Indent & "MeshFaceWraps {"

    'the number of faces
    FaceCount = Object.GetFaceCount
    FileObject.WriteLine Indent & Space(4) & CStr(CLng(FaceCount)) & ";"

    'write the face wraps
    For FaceIndex = 0 To FaceCount - 1

        Set Face = Object.GetFace(FaceIndex)

        Face.GetTextureTopology WrapU, WrapV

        'a different delimiter for the last face
        If FaceIndex = FaceCount - 1 Then
            Delimiter = ";"
        Else
            Delimiter = ","
        End If
        FileObject.WriteLine Indent & Space(4) & CStr(CLng(WrapU)) & ";; " & CStr(CLng(WrapV)) & ";;" & Delimiter

        'release the face
        Set Face = Nothing
    Next

    'write the closing texture coordinates block
    FileObject.WriteLine Indent & "}"


End Sub

'*********************************************************************************
' Purpose: write the texture coordinates for an object
'*********************************************************************************

Sub WriteTextureCoordinates(FileObject, Object, Level)

    Dim Indent
    Dim Delimiter
    Dim TextureCoordinateIndex
    Dim TextureCoordinateCount
    Dim U
    Dim V

    'determine the amount of fill
    Indent = Space(Level * 4)

    'the header
    FileObject.WriteLine Indent & "MeshTextureCoords {"

    'get the number of texture coordinates (there is one for each point)
    TextureCoordinateCount = Object.GetPointCount

    'write the number of texture coordinates
    FileObject.WriteLine Indent & Space(4) & CStr(CLng(TextureCoordinateCount)) & ";"

    'write the coordinates
    For TextureCoordinateIndex = 0 To TextureCoordinateCount - 1

        'if the last texture coordinate there is a different delimiter
        If TextureCoordinateIndex = TextureCoordinateCount - 1 Then
            Delimiter = ";"
        Else
            Delimiter = ","
        End If

        'get the texture coordinate
        Object.GetPointTextureCoordinate TextureCoordinateIndex, U, V

        'write the texture coordinate
        FileObject.WriteLine Indent & Space(4) & mCanvasApp.FormatScientific(U) & "; " & mCanvasApp.FormatScientific(V) & ";" & Delimiter

    Next

    'write the closing texture coordinates block
    FileObject.WriteLine Indent & "}"


End Sub

'*********************************************************************************
' Purpose: write the skeletal information for an object
'          warning: this is experimental and incomplete. it is here as an example
'*********************************************************************************

Sub WriteSkeletal(FileObject, Object, Level)

    Dim BoneCount
    Dim BoneIndex
    Dim Indent
    Dim Bone

    'Get the number of bones that affect this object
    BoneCount = Object.GetBoneCount

    'if we have any bones that affect this object
    If BoneCount > 0 Then
        'only comments for now
        Indent = "//RemoveMeForLimitedSkeletalInformation//" & Space(Level * 4)

        'output the header
        FileObject.WriteBlankLines(1)
        FileObject.WriteLine Indent & "XSkinMeshHeader {"
        FileObject.WriteLine Indent & Space(4) & "1000;  // nMaxSkinWeightsPerVertex (What specifically should this be? Will a really big number do?)"
        FileObject.WriteLine Indent & Space(4) & "1000;  // nMaxSkinWeightsPerFace (What specifically should this be? Will a really big number do?)"
        FileObject.WriteLine Indent & Space(4) & CStr(CLng(BoneCount)) & ";"
        FileObject.WriteLine Indent & "}"

        'output the bone effect
        For BoneIndex = 0 to BoneCount - 1
            'get the bone
            Set Bone = Object.GetBone(BoneIndex)

            'write the bone effect
            WriteBone FileObject, Bone, Level

        Next
    End If


End Sub

'*********************************************************************************
' Purpose: write the details of a bone
'*********************************************************************************

Sub WriteBone(FileObject, Bone, Level)

    Dim Indent
    Dim AffectedPointCount
    Dim AffectedPoint
    Dim AffectedPointIndex
    Dim Delimiter
    Dim Frame

    AffectedPointCount = Bone.GetAffectedPointCount

    'only comments for now
    Indent = "//RemoveMeForLimitedSkeletalInformation//" & Space(Level * 4)

    'get the parent frame of this bone
    Set Frame = Bone.GetParentFrame

    'output the header
    FileObject.WriteLine Indent & ""
    FileObject.WriteLine Indent & "SkinWeights {"
    FileObject.WriteLine Indent & Space(4) & """x3dc_" & CStr(CLng(Frame.GetID)) & """;"
    FileObject.WriteLine Indent & Space(4) & CStr(CLng(AffectedPointCount)) & ";"

    'the vertices affected
    For AffectedPointIndex = 0 To AffectedPointCount - 1

        'a different delimiter for the last one
        If AffectedPointIndex = AffectedPointCount - 1 Then
            Delimiter = ";"
        Else
            Delimiter = ","
        End If

        'get the point
        AffectedPoint = Bone.GetAffectedPoint(AffectedPointIndex)

        FileObject.WriteLine Indent & Space(4) & CStr(CLng(AffectedPoint)) & Delimiter
    Next

    'their Weight
    For AffectedPointIndex = 0 To AffectedPointCount - 1

        'a different delimiter for the last one
        If AffectedPointIndex = AffectedPointCount - 1 Then
            Delimiter = ";"
        Else
            Delimiter = ","
        End If

        FileObject.WriteLine Indent & Space(4) & "1.0" & Delimiter & " //can I output 1.0 for all? (meaning all bones have equal influence)"
    Next

    'the transform
    FileObject.WriteLine Indent & Space(4) & "0.0,0.0,0.0,0.0,0.0,0.0,0.0,0.0,0.0,0.0,0.0,0.0,0.0,0.0,0.0,0.0;; //What specifically should this be? I have already said what frame the object is on and the frames involved. Perhaps this is the transformation relative to the world?"

    FileObject.WriteLine Indent & "}"


End Sub

'*********************************************************************************
' Purpose: write the animation set header for a frame
'*********************************************************************************

Sub WriteAnimationSet(FileObject, Frame)

    'write the opening animation block
    FileObject.WriteLine "AnimationSet x3dc_0 {"

    WriteAnimationFrame FileObject, Frame, 0

    'write the closing of the block
    FileObject.WriteLine "}"


End Sub

'*********************************************************************************
' Purpose: write the animation information for a frame
'          Warning: this uses recursion!
'*********************************************************************************

Sub WriteAnimationFrame(FileObject, Frame, Level)

    Dim ChildLevel
    Dim ChildFrameCount
    Dim ChildFrameIndex
    Dim ChildFrame

    'determine the child level
    ChildLevel = Level + 1

    'don't export the root frame
    If Level <> 0 Then
        'write the opening frame block
        FileObject.WriteLine Space(4) & "Animation x3dc_" & CStr(CLng(Frame.GetID)) & " {"
        FileObject.WriteLine Space(8) & "{x3dc_" & CStr(CLng(Frame.GetID)) & "}"

        'the animation style
        FileObject.WriteLine Space(8) & "AnimationOptions { " & CStr(CLng(Frame.GetAnimationStyle)) & "; 0; }"

        'write the animation keys
        WriteAnimationFrameKeys FileObject, Frame

        'write the closing of the frame block
        FileObject.WriteLine Space(4) & "}"
    End if

    'get the # of childrend the frame has
    ChildFrameCount = Frame.GetChildCount

    'run throught the children
    For ChildFrameIndex = 0 To ChildFrameCount -1
        Set ChildFrame = Frame.GetChild(ChildFrameIndex)

        'Recursion!
        WriteAnimationFrame FileObject, ChildFrame, ChildLevel

        'release the frame
        Set ChildFrame = Nothing
    Next


End Sub

'*********************************************************************************
' Purpose: write a frame's animation keys
'*********************************************************************************

Sub WriteAnimationFrameKeys(FileObject, Frame)

    Dim KeyFrameIndex
    Dim KeyFrameCount
    Dim Time
    Dim X
    Dim Y
    Dim Z
    Dim R
    Dim KeyData
    Dim Delimiter

    'get the animation key data for Position
    FileObject.WriteLine Space(8) & "AnimationKey {"
    FileObject.WriteLine Space(12) & "2;"

    'get the number of position key frames
    KeyFrameCount = Frame.GetPositionKeyFrameCount

    'write the number of keyframes
    FileObject.WriteLine Space(12) & CStr(CLng(KeyFrameCount)) & ";"

    'run through the position keyframes
    For KeyFrameIndex = 0 to KeyFrameCount - 1
        'get the keyframe
        Frame.GetPositionKeyFrame KeyFrameIndex, Time, X, Y, Z

        KeyData = Space(12) & CStr(CLng(Time)) & "; " & "3; " & mCanvasApp.FormatScientific(X) & ", " & mCanvasApp.FormatScientific(Y) & ", " & mCanvasApp.FormatScientific(Z) & ";;"

        'a different delimiter for the final keyframe
        If KeyFrameIndex <> KeyFrameCount - 1 Then
            Delimiter = ","
        Else
            Delimiter = ";"
        End If

        FileObject.WriteLine KeyData & Delimiter
    Next

    'write the closing item
    FileObject.WriteLine Space(8) & "}"

    'get the animation key data for Rotation
    FileObject.WriteLine Space(8) & "AnimationKey {"
    FileObject.WriteLine Space(12) & "0;"

    'get the number of orientation key frames
    KeyFrameCount = Frame.GetOrientationKeyFrameCount

    'write the number of keyframes
    FileObject.WriteLine Space(12) & CStr(CLng(KeyFrameCount)) & ";"

    'run through the orientation keyframes
    For KeyFrameIndex = 0 to KeyFrameCount - 1
        'get the keyframe
        Frame.GetOrientationKeyFrame KeyFrameIndex, Time, X, Y, Z, R

        KeyData = Space(12) & CStr(CLng(Time)) & "; " & "4; " &  mCanvasApp.FormatScientific(R) & ", " & mCanvasApp.FormatScientific(X) & ", " & mCanvasApp.FormatScientific(Y) & ", " & mCanvasApp.FormatScientific(Z) & ";;"

        'a different delimiter for the final keyframe
        If KeyFrameIndex <> KeyFrameCount - 1 Then
            Delimiter = ","
        Else
            Delimiter = ";"
        End If

        FileObject.WriteLine KeyData & Delimiter
    Next

    'write the closing item
    FileObject.WriteLine Space(8) & "}"

End Sub